'Get file details of a given folder
Set objShell = CreateObject ("Shell.Application")
myFolder = ""

' Input via Arguments
If WScript.Arguments.Count > 0 then
	myFolder = WScript.Arguments.Item(0)
End if

'Input via Explorer
If myFolder = "" Then 
	Set f = objShell.BrowseForFolder(0, "Choose a folder", 0)
	If (Not f Is Nothing) Then
		If f = "Desktop" then
			Set WshShell = WScript.CreateObject("WScript.Shell") 
			myFolder = WshShell.SpecialFolders("Desktop")
			Set WshShell = Nothing
		Else
			myFolder =  f.Items.Item.Path
		End If
	End If
End If

If myFolder <> "" Then
	Call ProcFolder(myFolder)
End If

'Loop through all the files in the folder
Sub ProcFolder(dFolder)
	Temp = ""
	Set fso = CreateObject("Scripting.FileSystemObject")
	Set objFolder = objShell.Namespace(dFolder)
	For each dFile in objFolder.Items
		uFile = UCase(dFile.Name)
		If (Right(uFile,4) = ".MP3") then '<- Filter here
			Temp = Temp & "Name  : " & objFolder.GetDetailsOf (dFile, 0) & VbCrLf & _
				  "Title : " & objFolder.GetDetailsOf (dFile, 10) & VbCrLf & VbCrLf
			If Not fso.FileExists(dFolder & "\" & objFolder.GetDetailsOf (dFile, 10)) then
				'fso.CopyFile   dFolder & "\" & dFile.Name, dFolder & "\" & objFolder.GetDetailsOf (dFile, 10)
				'fso.DeleteFile dFolder & "\" & dFile.Name
			End If
		End If
	Next
	Set objFolder = Nothing
	Set fso = Nothing
	Wscript.echo Temp
End Sub

'   0       Name
'   1       Size
'   2       Type
'   3       Date Modified
'   4       Date Created
'   5       Date Accessed
'   6       Attributes
'   7       Status
'   8       Owner
'   9       Author
'   10      Title
'   11      Subject
'   12      Category
'   13      Pages